10 POKE53280,11:POKE53281,11:TR=18:SE=1:DIMA(300):DIMB(200)
15 HX$="0123456789ABCDEF"
18 P=0:INPUT"[147]PRINTER Y/N/Q ";YN$:IFYN$="Y"THENP=1
19 IFYN$="Q"THENPRINT"GOOD BYE...!":END
20 PRINT"[147][158]     SUPERDIRECTORY[153] (C)84 PSIDAC VBN"
25 IFP=1THENOPEN4,4:PRINT#4:PRINT#4,CHR$(16)"15SUPERDIRECTORY":PRINT#4:CLOSE4
30 PRINT"INSERT SOURCE DISK IN DRIVE"
35 INPUT"DISK NAME";DN$
40 IFPD=1THEN50
41 PRINT"PRESS F7"
42 GETA$:IFA$<>"[136]"THEN42
45 IFP=1THENOPEN4,4:PRINT#4,"DISK NAME = "DN$:PRINT#4:CLOSE4
50 OPEN15,8,15:OPEN2,8,2,"#":PRINT#15,"U1:"2;0;TR;SE
60 SYS49152
70 CLOSE2:CLOSE15
80 FORRP=0TO255
100 A(RP)=PEEK(RP+52992)
120 NEXT
125 TR=A(0):SE=A(1)
130 PRINT"[147]TYPE TRACK SECTOR NAME             BLKS"
132 IFPD=1THENOPEN4,4:GOTO138
133 IFP<>1THEN136
134 OPEN4,4:PRINT#4,"TYPE   TRACK   SECTOR      NAME               BLKS":PRINT#4
136 IFP=1THENPD=1
138 FORRP=2TO226STEP32:OK=1:FT$="   "
139 TK=A(RP+1):SK=A(RP+2):NB=A(RP+28):IFTK=0THENCLOSE4:GOTO200
140 IFA(RP)=0THENFT$="DEL":OK=1
145 IFA(RP)=130THENFT$="PRG":OK=1
150 IFA(RP)=132THENFT$="REL":OK=0
155 IFA(RP)=129THENFT$="SEQ":OK=0
160 PRINTFT$;
165 IFP=1THENPRINT#4,FT$;
172 PRINTTAB(5)TK;TAB(12)SK;
175 IFP=1THENPRINT#4,CHR$(16)"07"TK;CHR$(16)"16"SK;CHR$(16)"27";
178 IFOK=1THENB(C)=TK:B(C+1)=SK:C=C+2
180 PRINTTAB(18);:FORTX=3TO18:PRINTCHR$(A(RP+TX));:NEXT:PRINTTAB(34)NB
185 IFP=1THENFORTX=3TO18:PRINT#4,CHR$(A(RP+TX));:NEXT:PRINT#4,CHR$(16)"46"NB
190 NEXT:CLOSE4
200 IFA(0)<>0THENGOTO40
300 PRINT"PRESS F7"
305 GETA$:IFA$<>"[136]"THEN305
310 PRINT"[147]TRACK   SECTOR   HEX.ADD      DEC.ADD":PRINT
315 IFP<>1THEN320
318 OPEN4,4:PRINT#4:PRINT#4,"TRACK  SECTOR  HEX.ADD     DEC.ADD":PRINT#4
319 CLOSE4
320 PC=1:FORRP=0TOC-2STEP2
330 TR=B(RP):SE=B(RP+1)
340 OPEN15,8,15:OPEN2,8,2,"#":PRINT#15,"U1:"2;0;TR;SE
350 SYS49152
360 CLOSE2:CLOSE15:PC=PC+1
364 IFP=1THEN370
365 IFPC<>18GOTO370
367 PRINT"PRESS F7"
368 GETA$:IFA$<>"[136]"THEN368
369 PC=1:PRINT"[147]TRACK   SECTOR   HEX.ADD      DEC.ADD":PRINT
370 AL=PEEK(52994):AH=PEEK(52995):AT=256*AH+AL
375 GOSUB1000
380 PRINTTR;TAB(9)SE;TAB(18)D$;TAB(29)AT
382 IFP<>1THEN390
385 OPEN4,4
386 PRINT#4,TR;CHR$(16)"07"SE;CHR$(16)"16"D$;CHR$(16)"26"AT:CLOSE4
390 NEXT
400 PRINT"PRESS F7"
410 GETA$:IFA$<>"[136]"THEN410
999 RUN10
1000 X=AT:D$=""
1005 D(1)=INT(X/4096):X=X-(D(1)*4096):D(2)=INT(X/256):X=X-(D(2)*256)
1010 D(3)=INT(X/16):D(4)=X-(D(3)*16)
1020 FORI=1TO4:D$=D$+MID$(HX$,(D(I)+1),1):NEXT
1060 RETURN